Decriptare date

[Tibi_Tiby]

Buna ziua,

As dori sa ma ajutati in urmatoarea problema.
In celula A1 pun sa zicem 123 iar in celula B1 as dori sa imi apara L, Ma, Mi
Logica ar fi Luni=1, Marti=2...Duminica=7
Formula sau cod VBA. Multumesc.

[TudyBTH]

Copiati functia intr-un modul si introduceti "=GetDays(A1)" in B1

Cod: Selectaţi tot

Function GetDays(ByVal r As Range) As String
    Dim sN As String, sX As Integer
    Dim sDay As String, sDays As String
    Dim i As Integer
    
    Application.Volatile
    sN = CStr(r(1, 1).Value)
    For i = 1 To Len(sN)
        sX = Val(Mid(sN, i, 1))
        If sX > 0 And sX < 8 Then
            sDay = Array("L", "Ma", "Mi", "J", "V", "S", "D")(sX - 1)
            If Len(sDays) > 0 Then sDays = sDays & ","
            sDays = sDays & sDay
        End If
    Next i
    
    GetDays = sDays
End Function

[Indigo-ONE]

O alta varianta mai rapida...

Cod: Selectaţi tot

Function DeCript(Kc As String) As String
    Dim Ka As Long, arDays(), k As Long
    Kz = Array("L", "Ma", "Mi", "J", "V", "S", "D")
    For Ka = 1 To Len(Kc)
        k = Mid(Kc, Ka, 1) - 1
        DeCript = DeCript & ", " &  Kz(k)
    Next Ka
    DeCript = Right(DeCript, Len(DeCript) - 2)
End Function

in B1=DeCript(A1)

@TudyBTH,
Aceasta linie de cod "Application.Volatile" nu este necesara.

[Tibi_Tiby]

Buna seara,

Va multumesc mult pentru functiile oferite.
Ambele functioneaza perfect. O sa le studiez ca sa inteleg cum functioneaza.
Multumesc mult.