Calcul evaluare

[Dacoart]

Buna seara.

Incerc sa scriu o formula imbricata care nu-mi iesa nicicum

Celulele D2 - D6 din Sheet1 al tabelului atasat se vor popula cu valori luate din alte sheet-uri, cert este ca vor fi numere intregi (in sheeturile sursa vor fi la randul lor formule din alte sheeturi, etc.)
As avea nevoie ca in celulele E2 - E6 din Sheet1 sa se obtina nota, tinand cont de formulele din coloana B a sheetului 2. Astfel, nota poate fi diferita in functie de ponderea realizata.

Va multumesc anticipat !

evaluare.xls

[Indigo-ONE]

Salut,

Eu nu inteleg exact ce doresti.
Completeaza manual (fara formule) ce ar trebui sa apara in E2:E6, cum si functie de ce ai obtinut acele numere.

[Dacoart]

Bună dimineața și mulțumesc pentru interesul acordat.

Să luăm ca exemplu doar celul D2: o persoană poate realiza atribuțiile de serviciu în pondere de la 0-100 %, și pot fi următoarele situații:

- pentru intervalul de realizare de la 76-100, nota va fi de la 4,01-5 și o obțin prin aplicarea formulei din celula B2, Sheet2
- pentru intervalul de realizare de la 61-75, nota va fi de la 3,01-4 și o obțin prin aplicarea formulei din celula B3, Sheet2
- pentru intervalul de realizare de la 21-60, nota va fi de la 2,01-3 și o obțin prin aplicarea formulei din celula B4, Sheet2
- pentru intervalul de realizare de la 0-20, nota va fi de la 1-2 și o obțin prin aplicarea formulei din celula B5, Sheet2

Ce nu știu să fac este să determin excel să aplice una dintre formulele de la B2-B5 din Sheet2 în funcție de ce valoare va fi în celula D2, Sheet1

Am încercat să folosesc o formulă îmbricată cu funcția IF, dar nu mă pricep atât de bine și nu am reușit. Deasemeni, am încercat și soluția propusă într-un alt topic, ceva bazat pe VLOOKUP (viewtopic.php?f=8&t=5960&p=41865&hilit=comision#p41865), dar și aceasta mi-a fost greu de implementat deoarece situațiile nu sunt similare.


Mulțumesc.

[Indigo-ONE]

Salut,

In E2 si apoi "trasa" in jos, formula:

=IF(D2<21;D2/20+1;IF(D2<61;0,99*(D2-21)/39+2,01;IF(D2<76;0,99*(D2-61)/14+3,01;0,99*(D2-76)/24+4,01)))


E cam urata dar vroiam sa vad daca functioneaza, desigur ca se poate si o formula mai eleganta ....
Te rog sa o testezi deoarece nu e testata intensiv (am lucrat doar pe telefon).

Sper sa spui daca a functionat.

[Dacoart]

Pare să funcționeze excelent, singura chestie deranjantă este că dacă D2 e blank, formula returnează valoarea 1 în E2, dar nu cred să fie o problemă deoarece nu va fi D2...D6 niciodată blank.

O dau spre testare celui care mi-a cerut-o inițial și revin cu o confirmare, dar din ce văd eu, funcționează minunat.

Mersi tare mult !

[Indigo-ONE]

Mai poti pune un IF:

=if(d2="";""; aici pune formula pe care ti-am dato)

Sau poti folosi CF (Conditional formatting)


P.S. Daca folosesti excel 2010 de ce ai pus fisier cu extensia .xls?

[Dacoart]

P.S. Daca folosesti excel 2010 de ce ai pus fisier cu extensia .xls?

Mă așteptam la întrebarea asta Am întrebat-o pe soția mea același lucru, așa l-a primit și ea. Bănuiesc eu că acest fișier circulă prin mai multe birouri și pe undeva o fi și vreun Office 2003, altfel nu-mi explic

[cip.st]

Am încercat să folosesc o formulă îmbricată cu funcția IF, dar nu mă pricep atât de bine și nu am reușit. Deasemeni, am încercat și soluția propusă într-un alt topic, ceva bazat pe VLOOKUP (viewtopic.php?f=8&t=5960&p=41865&hilit=comision#p41865), dar și aceasta mi-a fost greu de implementat deoarece situațiile nu sunt similare.

Formula pe baza aceleiași abordări:

Cod: Selectaţi tot

=CHOOSE(MATCH(D2,{0,21,61,76,101},1),D2/20+1,0.99*(D2-21)/39+2.01,0.99*(D2-61)/14+3.01,0.99*(D2-76)/24+4.01)

Ideea la această abordare este să definești un vector ordonat crescător, care să conțină capetele de interval deschise la dreapta. În cazul tău, vectorul este {0,21,61,76,101}.
Vectorul se definește astfel deoarece în formula MATCH, ultimul parametru, match_type este egal cu 1, ceea ce înseamnă că formula va întoarce poziția ultimei valori mai mici decât valoarea căutată.

Deasemeni ai putea înlocui formula din celula E7 cu:

Cod: Selectaţi tot

=SUMPRODUCT(B2:B6,E2:E6)/SUM(B2:B6)

PS. Ce nu înțeleg eu este de ce nu a fost adaptată formula de calcul a notei astfel încât să fie liniară pe fiecare interval.
Acum, primul punct din fiecare interval, cu excepția primului, valorează 0,01 la notă, iar următoarele valorează 0,025, 0,0(6) și resectiv 0,04.
Dacă formula în loc de:

Cod: Selectaţi tot

=0.99*(D2-capăt stânga închis)/(lungime interval -1)+numar interval +0.01

ar fi fost:

Cod: Selectaţi tot

(D2-capăt stânga deschis)/(lungime interval)+număr interval

de exemplu pentru intervalul 2:

Cod: Selectaţi tot

(D2-20)/40+2

atunci fiecare punct procentual dintr-un interval ar fi avut aceeași valoare!