Valori text care nu apar pe toate coloanele

[knoppyx]

Salutare. Am o problema pe care nu o pot rezolva nici dupa multele cautari pe google.

Am un tabel cu 6 coloane in care unele valori pot sa existe sau nu in toate cele 6 coloane, unele valori exista doar in 3 din 6 coloane. Eu vreau sa imi arate acele valori care nu apar in toate cele 6 coloane. Cum spuneam mai sus, am valori care pot fi prezente in doar 3 din cele 6 coloane. Aceste valori as vrea sa mi le scoata cumva in evidenta. Am atasat si fisierul in cazua.

Ex. "ABS en regulation" (A2) este prezent doar pe coloanele A, B si D. Aceasta valoare (+celelalte in aceeasi situatie) vreau sa mi-o evidentieze cumva. Am incercat cu Conditional Formatting dar nu i-am dat de cap.
IMAGINE EXEMPLU


Mersi frumos

[TudyBTH]

Buna,

daca am inteles bine ceea ce doriti, ar putea fi folosita urmatoarea formula in Conditional Formatting

Cod: Selectaţi tot

=COUNTIF($A$2:$A$97;A2)*COUNTIF($B$2:$B$97;A2)*COUNTIF($C$2:$C$97;A2)*COUNTIF($D$2:$D$97;A2)*COUNTIF($E$2:$E$97;A2)*COUNTIF($F$2:$F$97;A2)=0

formula face produsul intre numarul de aparitii al fiecarui element, pe fiecare dintre coloane. Deci, daca pe una dintre coloane elementul de referinta apare de "0" (zero) ori, formula va intoarce "TRUE"

Vedeti fisierul atasat

[knoppyx]

Este perfect Multumesc frumos.

[TudyBTH]

In cazul in care datele pe care dorilti sa le marcati au o structura variabila (vor fi adaugate/sterse linii sau coloane), este indicat sa folositi un nume definit dinamic pentru a nu incarca inutil mai multe celule cu Conditional Formatting (functionare greoaie a fisierului).

In acest caz va trebui sa folositi o definitie dinamica pentru zona cu date, de exemplu:
"allData" cu formula

Cod: Selectaţi tot

=OFFSET(Sheet1!$A$1;;;COUNTA(Sheet1!$A:$A);6)

tot pentru o implementare mai usoara in alt fisier, mai definiti un nume
"arr" cu formula

Cod: Selectaţi tot

=COLUMN(OFFSET(Sheet1!$A$1;;;1;ROWS(allData)))/COLUMN(OFFSET(Sheet1!$A$1;;;1;ROWS(allData)))

iar la Conditional formating folositi:

Cod: Selectaţi tot

=PRODUCT(MMULT(arr;COUNTIF(A2;allData)))=0